Langkah pertama yang harus dilakukan untuk membuat program yang berisi koneksi database adalah menyiapkan database yang akan digunakan untuk menyimpan data yang akan diinput melalui form yang akan dibuat dengan Visual Basic 6.0. Namun sebelumnya ada baiknya untuk menyiapkan satu direkori /folder untuk menyimpan file-file dalam project ini. Berikut ini adalah langkah-langkah untuk membuat databasenya:Buka program aplikasi MS Access 2003 dengan mengklik Start-All Programs -Microsoft Office-Microsoft Office Access 2003. Untuk membuat Database yang baru klik menu File-New kemudian pada takspane New File pilih Blank database... Kemudian akan muncul kotak dialog File New Database, tentukan nama database yang akan dibuat pada File name misalnya dbMahasiswa dan lokasi penyimpanan database pada Save ini pada folder yang telah dibuat tadi dan klik Create.
Untuk menyimpan data mahasiswa diperlukan sebuah tabel yang akan dibuat dengan cara sebagai berikut: klik ganda Create tabel in design view dan masukan field-field dari tabel seperti berikut:
NIM : Text (Primary Key)Pada tabel di atas terlihat ada tujuh buah field yang terdiri dari nim, nama, jengkel, alamat, notlp, jurusan dan keterangan. Buat field nim sebagai primary key / pengenal dalam tabel tersebut. Simpan tabel tersebut dengan nama tblmahasiswa.
Nama : Text
Jengkel : Text
Alamat : Memo
Notlp : Text
Jurusan : Text
Keterangan : memo
Langkah selanjutnya adalah meng-convert database yang telah dibuat ke dalam format “Access 97 File Format”. Caranya adalah pilih menu Tools-Database Utilities- Convert Database-To Access 97 File Format.
Setelah itu akan muncul kotak dialog Convert Database To, isikan nama database yang baru pada file name dengan nama dataMahasiswa. Kemudian muncul peringatan pilih saja OK. Database ini siap untuk digunakan, selanjutnya anda dapat keluar dari program aplikasi MS Access. Langkah berikutnya adalah membuat tampilan form dengan menggunakan Visual Basic 6.0
Membuat Form dengan Visual Basic 6.0
Setelah kita membuat databasenya, langkah berikutnya adalah membuat intervace (antar muka) dengan menggunakan Visual Basic 6.0. Buka Visual Basic 6.0 dengan cara klik Start-All Programs-Microsoft Visual Basic 6.0- Microsoft Visual Basic 6.0.
Pada kotak dialog New Project pilih Standard EXE kemudian klik Open. Sebuah form yang masih kosong akan tampil dan siap untuk di isi sesuai dengan kebutuhan program yang akan kita buat. Selanjutnya tambahkan beberapa komponen dan atur tata letaknya seperti yang terlihat pada gambar di atas.
Setelah semua komponen, selanjutnya adalah mengatur Properties dari masing-masing komponen tersebut sesuai dengan tabel berikut:
Keterangan : * Beri nama berurutan sesuai dengan urutan label, misal: Label2=NIM, Label3=Nama, dst...Berikut ini adalah bentuk tampilan Form yang telah diatur propertiesnya seperti tabel di atas (Gambar Kiri) dan bentuk tampilan Form yang telah dimodifikasi (Gambar Kanan):
Penulisan Listing Program
Sebelum melakukan pengkodean, tambahkan terlebih dahulu referensi pada project agar perintah koneksi database dapat dijalankan, dengan cara: pilih menu Project-References. Kemudian akan muncul kotak dialog References Project1 seperti gambar berikut ini:
Beri centang pada Microsoft ActiveX Data Objects 2.7 Library dan klik tombol OK.
Ada baiknya sebelum kita melanjutkan ke langkah berikutnya simpan terlebih dahulu project ini di folder yang telah kita buat pada waktu membuat database.
Selanjutnya adalah menambahkan modul koneksi pada project yang kita buat dengan cara klik menu Project-Add Module pada kotak dialog Add Module pilih Module kemudian klik open. Tambahkan kode berikut pada module tersebut:
'---------------------------------------Simpan dan tutup modul tersebut. Kemudian tambahkan kode berikut pada form dengan cara klik menu “View-Code”
Dim cnn As ADODB.Connection
Dim rs As ADODB.Recordset
Sub Koneksi(cnn, rs)
Set cnn = New ADODB.Connection
Set rs = New ADODB.Recordset
cnn.ConnectionString = _
"Provider=Microsoft.Jet.OLEDB.3.51; " & _
"Data Source=" & App.Path & "\DataMahasiswa.MDB"
cnn.Open
End Sub
Sub Tutup_Koneksi(cnn)
cnn.Close
Set cnn = Nothing
End Sub
'---------------------------------------
'--------------------------------------Jika semua kode di atas telah selesai diketik, ada baiknya simpan terlebih dahulu semua perubahan yang dilakukan. Jalankan program ini dengan menekan tombol F5 dan cobalah untuk memasukkan data ke dalam database. Untuk membuat program ini lebih menarik dan berguna tambahkan beberapa komponen dan listing program sesuai keinginan anda.
'Deklarasi Koneksi dan Rekordset
Dim cnn As ADODB.Connection
Dim rs As ADODB.Recordset
'Untuk mengosongkan field isian
Private Sub kosong()
txNim.Text = ""
txNama.Text = ""
txAlamat.Text = ""
opPria.Value = False
opWanita.Value = False
txjenkel.Text = ""
txNoTlp.Text = ""
cbJurusan.Text = ""
txKet.Text = ""
End Sub
'Untuk mengatur aksesibilitas tombol
Private Sub tombol(simpan, tambah, hapus, edit, keluar)
cmSimpan.Enabled = simpan
cmTambah.Enabled = tambah
cmHapus.Enabled = hapus
cmEdit.Enabled = edit
cmKeluar.Enabled = keluar
End Sub
'Untuk mengatur aksesibilitas field isian
Private Sub textisian(kondisi)
txNim.Enabled = kondisi
txNama.Enabled = kondisi
txAlamat.Enabled = kondisi
opPria.Enabled = kondisi
opWanita.Enabled = kondisi
txNoTlp.Enabled = kondisi
cbJurusan.Enabled = kondisi
txKet.Enabled = kondisi
End Sub
'Saat Tombol Edit Di klik
Private Sub cmEdit_Click()
Call textisian(True)
txNim.Enabled = False
Call tombol(True, False, False, False, True)
txNama.SetFocus
End Sub
'Saat Tombol Hapus Di klik
Private Sub cmHapus_Click()
Dim konfirmasi As String
'menampilkan konfirmasi pada saat tombol hapus diklik
konfirmasi = MsgBox("Anda yakin untuk menghapus data ini?", _
vbYesNo + vbExclamation, "Konfirmasi...")
If konfirmasi = vbYes Then
'Menghapus record yang ada pada tabel tblMahasiswa
cnn.Execute "delete from tblmahasiswa " & _
"where nim ='" & txNim.Text & "'"
Call kosong
Call tombol(False, True, False, False, True)
Else
Call tombol(False, True, True, True, True)
End If
cmTambah.SetFocus
End Sub
'Saat tombol keluar diklik
Private Sub cmKeluar_Click()
Unload Me
End Sub
'Saat tombol simpan diklik
Private Sub cmSimpan_Click()
'jika field isian masih ada yang kosong
If txNim.Text = "" Or _
txNama.Text = "" Or _
txAlamat.Text = "" Or _
txjenkel.Text = "" Or _
txNoTlp.Text = "" Or _
cbJurusan.Text = "" Then
MsgBox "Kolom isian masih ada yang kosong, tolong dilengkapi terlebih dahulu !", _
vbOKOnly + vbInformation, "Perhatian!"
txNim.SetFocus
'jika record belum tersimpan pada tabel
ElseIf txNim.Enabled = True Then
cnn.Execute "insert into tblmahasiswa " & _
"(nim, nama, jenkel, alamat, notlp, jurusan, keterangan) " & _
"values ('" & txNim.Text & "','" & txNama.Text & "', " & _
"'" & txjenkel.Text & "' ,'" & txAlamat.Text & "'," & _
"'" & txNoTlp.Text & "','" & cbJurusan.Text & "'," & _
"'" & txKet.Text & "')"
Call textisian(False)
Call tombol(False, True, True, True, True)
cmTambah.SetFocus
'jika record sudah ada pada tabel dan akan merubahnya(update table)
ElseIf txNim.Enabled = False Then
cnn.Execute " update tblmahasiswa set " & _
"nama= '" & txNama.Text & "'," & _
"alamat='" & txAlamat.Text & "'," & _
"jenkel='" & txjenkel.Text & "' ," & _
"notlp='" & txNoTlp.Text & "'," & _
"jurusan='" & cbJurusan.Text & "'," & _
"keterangan='" & txKet.Text & "'"& _
"where nim = '" & txNim.Text & "'"
Call textisian(False)
Call tombol(False, True, True, True, True)
cmTambah.SetFocus
End If
End Sub
'Saat tombol tambah diklik
Private Sub cmTambah_Click()
Call kosong
Call textisian(True)
Call tombol(True, False, False, False, True)
txNim.SetFocus
End Sub
'saat Form di buka (load)
Private Sub Form_Load()
'membuat koneksi dengan database dengan
'memanggil odul koneksi yang telah dibuat
Call Koneksi(cnn, rs)
'keadaan awal
Call kosong
Call textisian(False)
Call tombol(False, True, False, False, True)
'menambah item pada combobox cbJurusan
cbJurusan.AddItem "Teknik Informatika"
cbJurusan.AddItem "Sistem Komputer"
cbJurusan.AddItem "Manajemen Informatika"
cbJurusan.AddItem "Teknik Elektro"
cbJurusan.AddItem "Teknik Mesin"
End Sub
'saat Form di tutup (unload)
Private Sub Form_Unload(Cancel As Integer)
'menutup koneksi dengan database
Call Tutup_Koneksi(cnn)
End Sub
'saat opPria diklik
Private Sub opPria_Click()
txjenkel.Text = opPria.Caption
End Sub
'saat opWanita diklik
Private Sub opWanita_Click()
txjenkel.Text = opWanita.Caption
End Sub
'Saat txNim telah diisi
Private Sub txNim_LostFocus()
Dim perintah As String
If txNim.Text <> "" Then
perintah = "select * from tblmahasiswa where " & _
"nim = '" & txNim.Text & "'"
Set rs = cnn.Execute(perintah)
'jika record-nya telah ada dalam tabel maka
If Not rs.EOF Then
'tampilkan field yang lainnya sesuai dengan nim
txNim.Text = rs.Fields("nim")
txNama.Text = rs.Fields("nama")
txAlamat.Text = rs.Fields("alamat")
txjenkel.Text = rs.Fields("jenkel")
txNoTlp.Text = rs.Fields("notlp")
cbJurusan.Text = rs.Fields("jurusan")
txKet.Text = rs.Fields("keterangan")
Call textisian(False)
Call tombol(False, True, True, True, True)
cmTambah.SetFocus
End If
Else
End If
End Sub
'--------------------------------------
Untuk lebih jelasnya download penjelasan lengkapnya disini (file pdf)...
Untuk melihat hasil dari program yang telah dibuat download disini (vbp)...
Selamat mencoba....
No comments:
Post a Comment